-- card: 4440 from stack: in
-- bmap block id: 0
-- flags: 0000
-- background id: 3490
-- name: ShowHidden


-- part contents for background part 1
----- text -----
ShowHidden

-- part contents for background part 3
----- text -----
on showHidden
  -- give info about hidden fields or buttons; bkgnd or card
  if the paramcount<1 then
    put "field" into whch
  else
    put param(1) into whch
  end if
  if last char of whch is "s" then delete last char of whch
  put the number of words of whch into iii
  add 1 to iii
  put "Hidden " & whch & " - "
  put "put the number of " & whch & "s into howMany" into com1
  put "get the visible of " & whch into com2
  put "get the short name of " & whch into com3
  put "show " & whch into com4
  put "edit script of " & whch into com5
  do com1
  put 0 into cntr
  put 0 into lastone
  repeat with ii = 1 to howMany
    put com2 && ii into com
    do com
    if it is FALSE then
      put ii into lastone
      put com3 && ii into com
      do com
      put space & ii && ": " & it && "," after the message window
      add 1 to cntr
    end if
  end repeat
  if cntr > 0 then
    delete last char of the message window
    if cntr>1 then
      put "s" after word iii of the message window
    end if
    answer "Make visible or edit script?" with "Cancel" or "Visible" ¬
    or "Edit"
    if it is "Cancel" then exit showHidden
    if it is "Visible" then
      ask "Which one (specify number or ALL):" with "ALL"
      if it is empty then exit showHidden
      if it is "ALL" then
        repeat with ii = 1 to howMany
          put com4 && ii into com
          do com
        end repeat
      else
        put com4 && it into com
        do com
      end if
    else
      ask "Which one:" with lastone
      if it is empty then exit showHidden
      put com5 && it into com
      do com
    end if
  else
    put " None." after the message window
  end if
end showHidden

-- part contents for background part 4
----- text -----
This command will search the current card for hidden fields or buttons.  It will show a brief list of them and then give the opportunity to either make them visible or to edit the script of one of them.  Copy the handler below into your Home Card stack script

-- part contents for background part 5
----- text -----
6/28/88 15:16